CMake

Building CMake projects

  • Build libraries/binaries with CMake from sources using cmake rule
  • Use cmake targets in cc_library, cc_binary targets as dependency
  • Bazel cc_toolchain parameters are used inside cmake build
  • See full list of cmake arguments below 'example'
  • Works on Ubuntu, Mac OS and Windows (see special notes below in Windows section) operating systems

Example: (Please see full examples in ./examples)

The example for Windows is below, in the section 'Usage on Windows'.

  • In WORKSPACE.bazel, we use a http_archive to download tarballs with the libraries we use.
  • In BUILD.bazel, we instantiate a cmake rule which behaves similarly to a cc_library, which can then be used in a C++ rule (cc_binary in this case).

In WORKSPACE.bazel, put

workspace(name = "rules_foreign_cc_usage_example")

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

# Rule repository, note that it's recommended to use a pinned commit to a released version of the rules
http_archive(
   name = "rules_foreign_cc",
   sha256 = "c2cdcf55ffaf49366725639e45dedd449b8c3fe22b54e31625eb80ce3a240f1e",
   strip_prefix = "rules_foreign_cc-0.1.0",
   url = "https://github.com/bazelbuild/rules_foreign_cc/archive/0.1.0.zip",
)

load("@rules_foreign_cc//foreign_cc:repositories.bzl", "rules_foreign_cc_dependencies")

# This sets up some common toolchains for building targets. For more details, please see
# https://github.com/bazelbuild/rules_foreign_cc/tree/main/docs#rules_foreign_cc_dependencies
rules_foreign_cc_dependencies()

_ALL_CONTENT = """\
filegroup(
    name = "all_srcs",
    srcs = glob(["**"]),
    visibility = ["//visibility:public"],
)
"""

# pcre source code repository
http_archive(
    name = "pcre",
    build_file_content = _ALL_CONTENT,
    strip_prefix = "pcre-8.43",
    urls = [
        "https://mirror.bazel.build/ftp.pcre.org/pub/pcre/pcre-8.43.tar.gz",
        "https://ftp.pcre.org/pub/pcre/pcre-8.43.tar.gz",
    ],
    sha256 = "0b8e7465dc5e98c757cc3650a20a7843ee4c3edf50aaf60bb33fd879690d2c73",
)

And in the BUILD.bazel file, put:

load("@rules_foreign_cc//foreign_cc:defs.bzl", "cmake")

cmake(
    name = "pcre",
    cache_entries = {
        "CMAKE_C_FLAGS": "-fPIC",
    },
    lib_source = "@pcre//:all_srcs",
    out_static_libs = ["libpcre.a"],
)

then build as usual:

bazel build //:pcre

Usage on Windows

When using on Windows, you should start Bazel in MSYS2 shell, as the shell script inside cmake assumes this. Also, you should explicitly specify make commands and option to generate CMake crosstool file.

The default generator for CMake will be detected automatically, or you can specify it explicitly.

The tested generators: Visual Studio 15, Ninja and NMake. The extension .lib is assumed for the static libraries by default.

Example usage (see full example in ./examples/cmake_hello_world_lib): Example assumes that MS Visual Studio and Ninja are installed on the host machine, and Ninja bin directory is added to PATH.

cmake(
    # expect to find ./lib/hello.lib as the result of the build
    name = "hello",
    # This option can be omitted
    generate_args = [
        "-G \"Visual Studio 16 2019\"",
        "-A Win64",
    ],
    lib_source = ":srcs",
)

cmake(
    name = "hello_ninja",
    # expect to find ./lib/hello.lib as the result of the build
    lib_name = "hello",
    # explicitly specify the generator
    generate_args = ["-GNinja"],
    lib_source = ":srcs",
)

cmake(
    name = "hello_nmake",
    # explicitly specify the generator
    generate_args = ["-G \"NMake Makefiles\""],
    lib_source = ":srcs",
    # expect to find ./lib/hello.lib as the result of the build
    out_static_libs = ["hello.lib"],
)

Rules

cmake

Rule for building external library with CMake.

Example usage (generated)

load("@rules_foreign_cc//foreign_cc:cmake.bzl", "cmake")

cmake(
    # A unique name for this target.
    name = "",
    # Label with source code to build
    lib_source = "",
)

name

A unique name for this target.

additional_inputs

deprecated: Please use the build_data attribute.

additional_tools

deprecated: Please use the build_data attribute.

Optional. if true, link all the object files from the static library, even if they are not used.

build_args

Arguments for the CMake build command

build_data

Files needed by this rule only during build/compile time. May list file or rule targets. Generally allows any target.

cache_entries

CMake cache entries to initialize (they will be passed with -Dkey=value) Values, defined by the toolchain, will be joined with the values, passed here. (Toolchain values come first)

copts

Optional. Add these options to the compile flags passed to the foreign build system. The flags only take affect for compiling this target, not its dependencies.

data

Files needed by this rule at runtime. May list file or rule targets. Generally allows any target.

defines

Optional compilation definitions to be passed to the dependencies of this library. They are NOT passed to the compiler, you should duplicate them in the configuration options.

deps

Optional dependencies to be copied into the directory structure. Typically those directly required for the external building of the library/binaries. (i.e. those that the external build system will be looking for and paths to which are provided by the calling rule)

env

Environment variables to set during the build. $(execpath) macros may be used to point at files which are listed as data, deps, or build_data, but unlike with other rules, these will be replaced with absolute paths to those files, because the build does not run in the exec root. This attribute is subject to make variable substitution. No other macros are supported.Variables containing PATH (e.g. PATH, LD_LIBRARY_PATH, CPATH) entries will be prepended to the existing variable.

generate_args

Arguments for CMake's generate command. Arguments should be passed as key/value pairs. eg: ["-G Ninja", "--debug-output", "-DFOO=bar"]. Note that unless a generator (-G) argument is provided, the default generators are Unix Makefiles for Linux and MacOS and Ninja for Windows.

generate_crosstool_file

When True, CMake crosstool file will be generated from the toolchain values, provided cache-entries and env_vars (some values will still be passed as -Dkey=value and environment variables). If CMAKE_TOOLCHAIN_FILE cache entry is passed, specified crosstool file will be used When using this option to cross-compile, it is required to specify CMAKE_SYSTEM_NAME in the cache_entries

install

If True, the cmake --install comand will be performed after a build

install_args

Arguments for the CMake install command

lib_name

Library name. Defines the name of the install directory and the name of the static library, if no output files parameters are defined (any of static_libraries, shared_libraries, interface_libraries, binaries_names) Optional. If not defined, defaults to the target's name.

lib_source

Label with source code to build. Typically a filegroup for the source of remote repository. Mandatory.

linkopts

Optional link options to be passed up to the dependencies of this library

out_bin_dir

Optional name of the output subdirectory with the binary files, defaults to 'bin'.

out_binaries

Optional names of the resulting binaries.

out_data_dirs

Optional names of additional directories created by the build that should be declared as bazel action outputs

out_headers_only

Flag variable to indicate that the library produces only headers

out_include_dir

Optional name of the output subdirectory with the header files, defaults to 'include'.

out_interface_libs

Optional names of the resulting interface libraries.

out_lib_dir

Optional name of the output subdirectory with the library files, defaults to 'lib'.

out_shared_libs

Optional names of the resulting shared libraries.

out_static_libs

Optional names of the resulting static libraries. Note that if out_headers_only, out_static_libs, out_shared_libs, and out_binaries are not set, default lib_name.a/lib_name.lib static library is assumed

postfix_script

Optional part of the shell script to be added after the make commands

targets

A list of targets with in the foreign build system to produce. An empty string ("") will result in a call to the underlying build system with no explicit target set

tool_prefix

A prefix for build commands

tools_deps

deprecated: Please use the build_data attribute.

working_directory

Working directory, with the main CMakeLists.txt (otherwise, the top directory of the lib_source label files is used.)


Macros and Functions

cmake_variant

Wrapper macro around the cmake() rule to force usage of the given make variant toolchain.

Example usage (generated)

load("@rules_foreign_cc//foreign_cc:cmake.bzl", "cmake_variant")

cmake_variant(
    # The target name
    name = "",
    # The desired make variant toolchain to use, e.g
    toolchain = "",
)

name

The target name

toolchain

The desired make variant toolchain to use, e.g. @rules_foreign_cc//toolchains:preinstalled_nmake_toolchain

kwargs

Remaining keyword arguments